path: root/sysdeps/i386/memchr.S

/* memchr (str, chr, len) -- Return pointer to first occurrence of CHR in STR
	 less than LEN.  For Intel 80x86, x>=3.
   Copyright (C) 1994-2025 Free Software Foundation, Inc.
   This file is part of the GNU C Library.

   The GNU C Library is free software; you can redistribute it and/or
   modify it under the terms of the GNU Lesser General Public
   License as published by the Free Software Foundation; either
   version 2.1 of the License, or (at your option) any later version.

   The GNU C Library is distributed in the hope that it will be useful,
   but WITHOUT ANY WARRANTY; without even the implied warranty of
   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
   Lesser General Public License for more details.

   You should have received a copy of the GNU Lesser General Public
   License along with the GNU C Library; if not, see
   <https://www.gnu.org/licenses/>.  */

#include <sysdep.h>
#include "asm-syntax.h"

#define PARMS	4+8		/* space for 2 saved regs */
#define RTN	PARMS
#define STR	RTN
#define CHR	STR+4
#define LEN	CHR+4

	.text
ENTRY (__memchr)

	/* Save callee-safe registers used in this function.  */
	pushl %esi
	cfi_adjust_cfa_offset (4)
	pushl %edi
	cfi_adjust_cfa_offset (4)
	cfi_rel_offset (edi, 0)

	/* Load parameters into registers.  */
	movl STR(%esp), %eax	/* str: pointer to memory block.  */
	movl CHR(%esp), %edx	/* c: byte we are looking for.  */
	movl LEN(%esp), %esi	/* len: length of memory block.  */
	cfi_rel_offset (esi, 4)

	/* If my must not test more than three characters test
	   them one by one.  This is especially true for 0.  */
	cmpl $4, %esi
	jb L(3)

	/* At the moment %edx contains CHR.  What we need for the
	   algorithm is CHR in all bytes of the dword.  Avoid
	   operations on 16 bit words because these require an
	   prefix byte (and one more cycle).  */
	movb %dl, %dh		/* Now it is 0|0|c|c */
	movl %edx, %ecx
	shll $16, %edx		/* Now c|c|0|0 */
	movw %cx, %dx		/* And finally c|c|c|c */

	/* Better performance can be achieved if the word (32
	   bit) memory access is aligned on a four-byte-boundary.
	   So process first bytes one by one until boundary is
	   reached. Don't use a loop for better performance.  */

	testb $3, %al		/* correctly aligned ? */
	je L(2)			/* yes => begin loop */
	cmpb %dl, (%eax)	/* compare byte */
	je L(9)			/* target found => return */
	incl %eax		/* increment source pointer */
	decl %esi		/* decrement length counter */
	je L(4)			/* len==0 => return NULL */

	testb $3, %al		/* correctly aligned ? */
	je L(2)			/* yes => begin loop */
	cmpb %dl, (%eax)	/* compare byte */
	je L(9)			/* target found => return */
	incl %eax		/* increment source pointer */
	decl %esi		/* decrement length counter */
	je L(4)			/* len==0 => return NULL */

	testb $3, %al		/* correctly aligned ? */
	je L(2)			/* yes => begin loop */
	cmpb %dl, (%eax)	/* compare byte */
	je L(9)			/* target found => return */
	incl %eax		/* increment source pointer */
	decl %esi		/* decrement length counter */
	/* no test for len==0 here, because this is done in the
	   loop head */
	jmp L(2)

      /* We exit the loop if adding MAGIC_BITS to LONGWORD fails to
	 change any of the hole bits of LONGWORD.

	 1) Is this safe?  Will it catch all the zero bytes?
	 Suppose there is a byte with all zeros.  Any carry bits
	 propagating from its left will fall into the hole at its
	 least significant bit and stop.  Since there will be no
	 carry from its most significant bit, the <